wget https://github.com/Kitware/CMake/releases/download/v3.23.1/cmake-3.23.1.tar.gz
tar -xvf cmake-3.23.1.tar.gz
cd cmake-3.23.1
./configure
make -j16
sudo make install

cmake -S . -B build          # 配置：源码在 .，构建产物放 build/
cmake --build build -jN      # 构建（-jN 并行）

cmake -S . -B build -G "NMake Makefiles"
cmake --build build

# 指定 cmake 最低版本
cmake_minimum_required(VERSION 3.20)

# 项目名称
project(first_cmake)

# 生成可执行程序
add_executable(first_cmake 101first_cmake.cpp)

cmake -S . -B build          # 配置
cmake --build build         # 构建

set(VAR1 "测试变量VAR1的值")
message("VAR1= " ${VAR1})
message("VAR1 in string ${VAR1}")
message("\${VAR1} = ${VAR1}")     # 想打印字面 ${} 用 \ 转义

set(VAR2 "VAR1")
message("VAR2= " ${${VAR2}})      # 嵌套访问，取到 VAR1 的值

unset(VAR1)                        # 取消变量
message("\${VAR1} = ${VAR1}")

# 注意：多参数无分隔符，下面输出为“参数1参数2参数3”，不是带空格的
message("参数1" "参数2" "参数3")

# 本模块内的路径用 CMAKE_CURRENT_LIST_DIR（推荐）
${CMAKE_CURRENT_LIST_DIR}/include
# 引用其他模块用 PROJECT_SOURCE_DIR / CMAKE_SOURCE_DIR
${PROJECT_SOURCE_DIR}/modules/parameter/include
${PROJECT_SOURCE_DIR}/3rdpart/tinyxml2

set(BUILD_SHARED_LIBS ON)          # 后续 add_library 默认建动态库
add_definitions(-Dxlog_STATIC)     # 向 C++ 传宏；现代写法见“Target 与依赖管理”

message(" MSVC = " ${MSVC})
message(" WIN32 = " ${WIN32})
message(" UNIX = " ${UNIX})
message("CMAKE_SYSTEM_NAME = " ${CMAKE_SYSTEM_NAME})

# 把头文件也列进来：作用是让 IDE/工程生成器在项目树里显示（头文件本身不编译）
# 注意：并不是“列了头文件才会在头文件改动时重编”——重编靠编译器/CMake 的依赖扫描自动完成
add_library(${PROJECT_NAME} xlog.cpp xlog.h)

if(<conditional>)
elseif(<conditional>)
else()
endif()

if(1)
    message("1 is true")
endif()

if(0)
    message("0 is true")
else()
    message("0 is false")
endif()

if(VAR_NOT_DEF)                 # 未定义变量默认为假
    message("VAR_NOT_DEF is true")
else()
    message("VAR_NOT_DEF is false")
endif()

if("ON")
    message("String ON is true")
endif()

set(VAR1 123)

if(VAR1 EQUAL 123)
    message("VAR1 EQUAL 123")
endif()

# 推荐用 STREQUAL
if(VAR1 STREQUAL "123")
    message("VAR1 STREQUAL 123")
endif()

set(STR1 "abcd1234")

if(STR1 MATCHES "[a-z]+")
    message("MATCHES [a-z]+ true")
endif()

if(STR1 MATCHES "^[a-z]+$")
    message("full match")
else()
    message("no full match")
endif()

set(VAR1 "VALUE1-1" CACHE STRING "cache doc")
set(VAR1 "VALUE1-2" CACHE STRING "cache doc")        # 缓存变量二次赋值不生效
message("VAR1 = ${VAR1}")
set(VAR1 "VALUE1-3" CACHE STRING "cache doc" FORCE)  # FORCE 强制修改

set(VAR_BOOL1 "ON"  CACHE BOOL "bool 001")
set(VAR_FILE "filepath" CACHE FILEPATH "var file path")
set(VAR_PATH "path"     CACHE PATH "var path")
set(VAR_INTERNAL "internal var" CACHE INTERNAL "internal var")
option(OPT1 "opt1 doc" OFF)
option(OPT2 "opt2 doc" ON)

set(normalVar1 "normal var1")
set(normalVar1 "Cache var1" CACHE STRING "cache doc")
message("normalVar1 = ${normalVar1}")
message("CACHE{normalVar1} = $CACHE{normalVar1}")

# CMP0126：NEW 保留同名普通变量；OLD 仅在新建缓存项、原缓存项无类型、FORCE/INTERNAL 等条件下移除普通变量
cmake_policy(SET CMP0126 OLD)

cmake -S . -B b5 -D PARA1=para00001

include("cmake/test_cmake.cmake")
include("cmake/test_cmake1.cmake" OPTIONAL)                   # 找不到不报错
include("cmake/test_cmake1.cmake" OPTIONAL RESULT_VARIABLE ret)
message("ret = ${ret}")                                       # 未找到为 NOTFOUND
include("cmake/test_cmake.cmake" OPTIONAL RESULT_VARIABLE ret)
message("ret = ${ret}")                                       # 找到则为绝对路径

message("参数1" #[[中间注释]] "参数2")   # 输出：参数1参数2

set_property(GLOBAL PROPERTY TEST_GLOBAL "test global 001")
set_property(SOURCE myfile.cpp PROPERTY COMPILE_FLAGS "-Wall")
get_property(result TARGET my_target PROPERTY CXX_STANDARD)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
# 或 target 级：target_compile_features(app PUBLIC cxx_std_11)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g")

# 更稳妥的等价写法
string(APPEND CMAKE_CXX_FLAGS " -g")

# 正确处理列表语义
add_compile_options(-g)

cmake_minimum_required(VERSION 3.0)
project(chat)
# 最终可执行文件输出路径
set(EXECUTABLE_OUTPUT_PATH ${PROJECT_SOURCE_DIR}/bin)
# 头文件搜索路径（目录作用域，可被后续 add_subdirectory 的子目录继承；不会递归搜索磁盘上的子目录）
include_directories(${PROJECT_SOURCE_DIR}/include)

aux_source_directory("./src" LIB_SRCS)

file(GLOB SRC2 ${CMAKE_CURRENT_SOURCE_DIR}/src/*.cpp)
file(GLOB H_FILE "${INCLUDE_PATH}/xcpp/*.h")

set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/lib")   # .so
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/bin")   # 可执行/dll/pdb
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}/lib")   # .a 静态库

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

{
  "cmake.configureArgs": [
    "-DCMAKE_EXPORT_COMPILE_COMMANDS=ON"
  ]
}

cmake --build . --target help          # 查看所有目标
cmake --build . --target 101first_cmake.i   # 预处理
cmake --build . --target 101first_cmake.s   # 编译到汇编
cmake --build . --target 101first_cmake.o   # 汇编到目标文件
cmake --build . --target clean              # 清理

set(CMAKE_VERBOSE_MAKEFILE ON)     # 默认 OFF

message(FATAL_ERROR "TEST FATAL ERROR") # 终止；其后不执行
message(SEND_ERROR  "TEST SEND ERROR")  # 继续但不生成目标
message(WARNING "TEST WARNING")
message("TEST NOTICE")                  # 等同无级别
message(STATUS  "TEST STATUS")
message(VERBOSE "TEST VERBOSE")         # 需 --log-level=VERBOSE 才显示

cmake -S . -B build --log-level=VERBOSE
cmake -S . -B build --log-level=VERBOSE > log.txt        # 仅 stdout 重定向到文件
cmake -S . -B build --log-level=VERBOSE > log.txt 2>&1   # stdout 和 stderr 都写入 log.txt

message(CHECK_START "查找 xcpp")
set(CMAKE_MESSAGE_INDENT "--")     # 嵌套查找的缩进
message(CHECK_START "查找 xlog")
message(CHECK_PASS  "成功")
message(CHECK_START "查找 xtheadpool")
message(CHECK_FAIL  "失败")
set(CMAKE_MESSAGE_INDENT "")       # 取消缩进
message(CHECK_FAIL "失败")

# \033[显示方式;前景色;背景色m ... \033[0m
#   显示方式：0-默认 1-高亮 2-低亮 3-下划线 4-闪烁 5-慢闪 6-快闪 7-反白 8-隐藏 9-划掉
string(ASCII 27 Esc)
set(Red  "${Esc}[0;31m")     # 红色
set(Blue "${Esc}[1;34m")     # 蓝色高亮
set(RedB "${Esc}[1;31;40m")  # 红字黑底
set(End  "${Esc}[0m")

message("${Red} 红色内容${End}")
message("${Blue} 蓝色内容${End}")
message("${RedB} 红色+背景内容${End}")

add_library(<name> [STATIC|SHARED|MODULE] <sources>...)

add_library(xlog_static STATIC src/xlog.cpp)  # libxlog_static.a
add_library(xlog_shared SHARED src/xlog.cpp)  # libxlog_shared.so

option(BUILD_SHARED_LIBS "Build shared libraries" OFF)
add_library(xlog src/xlog.cpp)

cmake -S . -B build-shared -DBUILD_SHARED_LIBS=ON
cmake --build build-shared

library_demo/
├── CMakeLists.txt
├── include/
│   └── xlog.h
├── src/
│   └── xlog.cpp
└── main.cpp

cmake_minimum_required(VERSION 3.20)
project(library_demo LANGUAGES CXX)

add_library(xlog STATIC
    src/xlog.cpp
)

target_include_directories(xlog PUBLIC
    "${CMAKE_CURRENT_SOURCE_DIR}/include"
)

add_executable(app main.cpp)
target_link_libraries(app PRIVATE xlog)

cmake -S . -B build
cmake --build build
./build/app

set_target_properties(xlog PROPERTIES POSITION_INDEPENDENT_CODE ON)

add_library(<name> <type> IMPORTED [GLOBAL])

imported_library_demo/
├── CMakeLists.txt
├── main.cpp
└── third_party/
    └── xlog/
        ├── include/
        │   └── xlog.h
        └── lib/
            └── libxlog.a

cmake_minimum_required(VERSION 3.20)
project(imported_library_demo LANGUAGES CXX)

set(XLOG_ROOT "${CMAKE_CURRENT_LIST_DIR}/third_party/xlog")

add_library(xlog::xlog STATIC IMPORTED)
set_target_properties(xlog::xlog PROPERTIES
    IMPORTED_LOCATION "${XLOG_ROOT}/lib/libxlog.a"
    INTERFACE_INCLUDE_DIRECTORIES "${XLOG_ROOT}/include"
)

add_executable(app main.cpp)
target_link_libraries(app PRIVATE xlog::xlog)

cmake -S . -B build
cmake --build build
./build/app

add_library(xlog::xlog SHARED IMPORTED)
set_target_properties(xlog::xlog PROPERTIES
    IMPORTED_LOCATION "${XLOG_ROOT}/lib/libxlog.so"
    INTERFACE_INCLUDE_DIRECTORIES "${XLOG_ROOT}/include"
)

find_package(Threads REQUIRED)
target_link_libraries(xlog::xlog INTERFACE Threads::Threads)

target_include_directories(<target> [PRIVATE|PUBLIC|INTERFACE] <dirs>)

target_link_libraries(app PRIVATE foo)   # foo 仅 app 自己用
target_link_libraries(app PUBLIC  foo)   # app 及其下游都继承 foo 的 usage requirements
target_link_libraries(app INTERFACE foo) # app 自己不用，只有下游用

cmake_minimum_required(VERSION 3.20)
project(test_xlog)
add_executable(test_xlog test_log.cpp)
include_directories("../xlog")            # 头文件路径

find_library(FDK fdk-aac PATHS ${CMAKE_CURRENT_LIST_DIR}/lib)
target_link_libraries(test_xlog PRIVATE ${FDK})

add_library(fdkaac STATIC IMPORTED)
set_target_properties(fdkaac PROPERTIES
    IMPORTED_LOCATION ${CMAKE_CURRENT_LIST_DIR}/lib/libfdk-aac.a
)
target_link_libraries(test_xlog PRIVATE fdkaac)

set_target_properties(<目标1> <目标2> ...
    PROPERTIES
        <属性1> <值1>
        <属性2> <值2>
)

find_package(Threads REQUIRED)
target_link_libraries(app PRIVATE Threads::Threads)   # 导入目标自带 usage requirements

target_compile_options(app PRIVATE $<$<CONFIG:Debug>:-O0 -g>)
target_include_directories(lib PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>)

install(TARGETS app
    RUNTIME DESTINATION bin      # 可执行文件
    LIBRARY DESTINATION lib      # .so
    ARCHIVE DESTINATION lib)     # .a

cmake -S . -B build -DCMAKE_TOOLCHAIN_FILE=arm.cmake

# arm.cmake
set(CMAKE_SYSTEM_NAME Linux)
set(CMAKE_SYSTEM_PROCESSOR arm)
set(CMAKE_C_COMPILER   arm-mol-linux-uclibcgnueabihf-gcc)
set(CMAKE_CXX_COMPILER arm-mol-linux-uclibcgnueabihf-g++)
set(CMAKE_SYSROOT      /path/to/arm-mol-linux-uclibcgnueabihf/sysroot)
set(CMAKE_FIND_ROOT_PATH ${CMAKE_SYSROOT})
# 让 find_* 只在 sysroot 里找库/头，程序仍用主机的
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)

file a.out                       # 确认目标架构
arm-...-readelf -h a.out         # 架构、ABI
arm-...-readelf -d a.out         # NEEDED 动态库依赖、RPATH

mips-linux-uclibc/
├── include/c++/        # C++ 标准库头文件
├── libc/               # 默认 sysroot 根目录 ⭐
│   ├── usr/include/    # 系统头文件
│   ├── usr/lib/        # 系统库文件
│   ├── glibc/          # glibc 变体
│   ├── soft-float/     # 软浮点变体
│   └── mfp32/          # mfp32 浮点变体

arm-mol-linux-uclibcgnueabihf/
├── bin/
├── include/            # 工具链头文件
├── lib/                # 工具链库文件
├── debug-root/
└── sysroot/            # 默认 sysroot 根目录 ⭐
    ├── lib/            # 系统库文件
    ├── sbin/
    └── usr/
        ├── include/    # 系统头文件
        └── lib/        # 系统库文件